AC_PREREQ([2.71])

AC_INIT([SVG C Library],[1.1.0],[Andrey V.Kosteltsev <kx@radix-linux.su>],[svgc],[https://radix-linux.su])

AC_SVGC_REQUIRE_BASH

AC_SVGC_HEADLINE([svgc], [SVG C Library], [SVGC_VERSION],dnl
[Copyright (c) 1999-2026 Andrey V.Kosteltsev])dnl

AC_MSG_CFG_PART(Getting the canonical system type)
dnl
dnl NOTE: Следующие вызовы должны осуществляться строго до
dnl       вызова AM_INIT_AUTOMAKE .
dnl
dnl Для библиотеки достаточно вызвать AC_CANONICAL_HOST и при этом
dnl будут определены build_alias и host_alias. Однако опция --target
dnl будет запрещена.
dnl
dnl Для программ достаточно задать AC_CANONICAL_TARGET и при этом
dnl будут определены build_alias, host_alias и target_alias. Естественно
dnl будут доступны все три опции: --build, --host, и --target .
dnl

AC_CANONICAL_HOST
AC_CANONICAL_TARGET
AC_USE_SYSTEM_EXTENSIONS

dnl Должна вызываться строго после AC_CANONICAL_TARGET .
AC_ARG_PROGRAM

AC_MSG_CFG_PART(Init Automake environment)
AM_INIT_AUTOMAKE([foreign subdir-objects dist-xz no-dist-gzip])

AC_CONFIG_SRCDIR([acsite.m4])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_MACRO_DIRS([m4])

AC_MSG_CFG_PART([Test for Build Tools])
AC_PROG_CC

AC_MSG_CFG_PART([Test for GNU libtool])
LT_PREREQ([2.4.6])
LT_INIT
AC_SUBST([LIBTOOL_DEPS])

AC_MSG_CFG_PART([Test for libtool VERSION Information])
AC_SVGC_LT_VERSION_INFO([1:0:0])

AC_MSG_CFG_PART([Checking System Headers])
AC_CHECK_HEADERS([stdio.h stdlib.h string.h unistd.h])

AC_MSG_CFG_PART([Build Parameters])
AC_MSG_CHECKING([whether static libraries are enabled])
AC_MSG_RESULT([$enable_static])
AC_MSG_CHECKING([whether shared libraries are enabled])
AC_MSG_RESULT([$enable_shared])

AC_MSG_CFG_PART([OUTPUT])
AC_CONFIG_FILES([
 Makefile
 src/Makefile
 tests/Makefile
 svgc-config/Makefile
 svgc-config/svgc-config
 svgc.pc
 examples/Makefile
 examples/css-file/Makefile
 examples/oscilator/Makefile
 examples/script-file/Makefile
])
AC_CONFIG_COMMANDS([svgc-config-chmod], [chmod +x svgc-config/svgc-config])
AC_OUTPUT

if test -f "config.h"; then
  echo ""
  echo "Now you can run:"
  echo "  \`${TB}make${TN}'           to compile,"
  echo "  \`${TB}make install${TN}'   to make and install ${TB}SVGC${TN},"
  echo "  \`${TB}make dist${TN}'      to create distributable tarballs, or"
  echo "  \`${TB}make distclean${TN}' to clean before configure for another target."
  echo "Good luck."
  echo ""
fi